//A tiny time lapse application (probably the tiniest)
//Cem Sina Çetin 2012
 
import processing.video.*;
 
Capture cam;
int pixelCount;
int tick;
int filename;
int seconds;
String path;
File file;
 
void setup()
{
  size(640,480);
 
  tick = 0;
  seconds = 30; //the time interval between two captured images.
  filename = 0;
 
  //root directory for the time lapse sessions.
  do
  {
    path = selectFolder();
  }while(path == null);
 
  path = path+"/"+
         Integer.toString(day())+"."+
         Integer.toString(month())+"."+
         Integer.toString(year())+"/";
 
  println("save directory: "+path);
 
  file = new File(path);
  if(file.isDirectory())
  {
    filename = file.listFiles().length;
    println("existing files in folder: "+Integer.toString(filename));
  }
 
  println("for 25fps, the time lapse of a single day will take: "+
          Float.toString(((86400.0/seconds)/25)/60) +
          " minutes.");
 
  frameRate(1);
  cam = new Capture(this, width, height, 30);
  cam.start();
  pixelCount = width*height;
  loadPixels();
}
 
void draw()
{
  tick++;
  if(tick > seconds && cam.available())
  {
    cam.read();
    cam.loadPixels();
    for(int i = 0; i<pixelCount; i++)
       pixels[i] = cam.pixels[i];
    updatePixels();  
    save(path+Integer.toString(filename)+".jpg");
    println("Image "+Integer.toString(filename)+".jpg is saved.");
    filename++;
    tick = 0;
  }
}